Clarion Community Help

COMBO(picture),FROM( ) ,AT( ) [,CURSOR( )] [,USE( )] [,LAYOUT( )][,DISABLE] [,KEY( )] [,MSG( )] [,HLP( )]

The COMBO control places a data entry field with an associated list of data items on the WINDOW or TOOLBAR (not valid in a REPORT) at the position and size specified by its AT attribute (a combination of an ENTRY and LIST control). The user may type in data or select an item from the list. The entered data is not automatically validated against the entries in the list. The data entry portion of the COMBO acts as an “incremental locator” to the list–as the user types each character, the highlight bar is positioned to the closest matching entry.

A COMBO with the DROP attribute displays only the currently selected data item on screen until the control has focus and the user presses the down arrow key, or CLICKS ON the the icon to the right of the displayed data item. When either of these occurs, the selection list appears (“drops down”) to allow the user to select an item.

A COMBO with the IMM attribute generates an EVENT:NewSelection every time the user moves the highlight bar to another selection, or presses any key (all keys are implicitly ALRTed). This allows an opportunity for the source code to re-fill the display QUEUE, or get the currently highlighted record to display other fields from the record. A COMBO with the VCR attribute has scroll control buttons like a Video Cassette Recorder to the left of the horizontal scroll bar (if there is one). These buttons allow the user to use the mouse to scroll through the list.

Regarding the runtime alignment properties (PROP:Left, PROP:LeftOffset, PROP:Right, PROP:RightOffset, PROP:Center, PROP:CenterOffset, PROP:Decimal, PROP:DecimalOffset) applied to the drop (list) box, these properties are applied only to the ENTRY part of the COMBO control by default. To apply these properties to the LIST component, use them in conjunction with the PROP:ListFeq property:

?Drop {PROP:Left} = TRUE                                ! Set static part left aligned

(?Drop {PROP:ListFeq}) {PROP:Right} = TRUE ! Set lit part right aligned

Alignment properties defined for drop boxes in the WINDOW declaration are applied to both ENTRY and LIST by default.

Events Generated:

Example:

MDIChild WINDOW('Child One'),AT(0,0,320,200),MDI,MAX,HVSCROLL

         COMBO(@S8),AT(0,0,20,20),USE(C1),FROM(Que)

         COMBO(@S8),AT(20,0,20,20),USE(C2),FROM(Que),KEY(F10Key)

         COMBO(@S8),AT(40,0,20,20),USE(C3),FROM(Que),MSG('Button 3')

         COMBO(@S8),AT(60,0,20,20),USE(C4),FROM(Que),HLP('Check4Help')

         COMBO(@S8),AT(80,0,20,20),USE(C5),FROM(Q) |

         ,FORMAT('5C~List~15L~Box~'),COLUMN

         COMBO(@S8),AT(100,0,20,20),USE(C6),FROM(Que),FONT('Arial',12)

         COMBO(@S8),AT(120,0,20,20),USE(C7),FROM(Que),DROP(8)

         COMBO(@S8),AT(140,0,20,20),USE(C8),FROM(Que),HVSCROLL,VCR

         COMBO(@S8),AT(160,0,20,20),USE(C9),FROM(Que),IMM

         COMBO(@S8),AT(180,0,20,20),USE(C10),FROM(Que),CURSOR(CURSOR:Wait)

         COMBO(@S8),AT(200,0,20,20),USE(C11),FROM(Que),ALRT(F10Key)

         COMBO(@S8),AT(220,0,20,20),USE(C12),FROM(Que),LEFT

         COMBO(@S8),AT(240,0,20,20),USE(C13),FROM(Que),RIGHT

         COMBO(@S8),AT(260,0,20,20),USE(C14),FROM(Que),CENTER

         COMBO(@N8.2),AT(280,0,20,20),USE(C15),FROM(Que),DECIMAL

         COMBO(@S8),AT(300,0,20,20),USE(C16),FROM('Apples|Peaches|Pumpkin|Pie')

         COMBO(@S8),AT(320,0,20,20),USE(C17),FROM('TBA')

        END

CODE

OPEN(MDIChild)

?C17{PROP:From} = 'Live|Long|And|Prosper'   !Runtime FROM attribute assignment

ACCEPT

 CASE ACCEPTED()

 OF ?C1

  LOOP X# = 1 to RECORDS(Que)               !Check for user's entry in Que

   GET(Que,X#)

   IF C1 = Que THEN BREAK.                  !Break loop if present

  END

  IF X# > RECORDS(Que)                      !Check for BREAK

   Que = C1                                 !and add the entry

   ADD(Que)

  END

 END

END

See Also:

LIST

ENTRY

PROP:ListFeq